[VBA]

AccessからOutLookをコントロールする

[動作環境]

Microsoft Windows 2000
Microsoft Access 2000
Microsoft OutLook 2000

[概要]

Accessのフォーム上からOutLookを起動し、メールの送受信などのコントロールが行えます。なおここで紹介するのは、OutLookの送信トレイへメールを送る方法と、受信トレイの新着メールを確認する方法です。実際に送受信するにはOutLook側での定期的な送受信などの設定が必要になります。

[手順]

1: 変数宣言

Accessで新規フォームを作成し、モジュールレベルで下記のコードを記述して下さい。

Dim m_OLApp As Object
Dim m_Namespace As Object
Dim m_Folder As Object
Dim m_Item As Object
Dim m_RecvItem As Object
	

2： OutLook起動

Accessのフォームオープンのイベントプロシージャに下記のコードを記述して下さい。

'outlookの起動
Set m_OLApp = CreateObject("Outlook.Application")
Set m_Namespace = m_OLApp.GetNamespace("MAPI")
Set m_Folder = m_Namespace.GetDefaultFolder(6)
m_Folder.Display
      

3： 送信トレイにメールを送る

フォーム上にコマンドボタンを作成し、クリックのイベントプロシージャに下記のコードを記述して下さい。

'メール作成
Set l_Item = m_OLApp.CreateItem(olMailItem)
l_Item.To = "xxx@xxx.xx.xx"	'送信先アドレス
l_Item.Subject = "テスト"		'件名
l_Item.Body = "送れましたか？" 	'本文
l_Item.send 	  
	  

また l_Item.send の前に

l_Item.Display

と加えるとメール新規作成ダイアログが現れます。

4： 受信トレイのメールを見る

コマンドボタンを作成し、クリックイベントプロシージャに下記のコードを記述して下さい。

Dim l_unread As Integer '未開封数
Dim l_cnt As Integer '全受信メール数
Dim m As Integer 'カウント用メール総数
Dim i As Integer '未読メールカウント用

l_unread = m_Folder.UnReadItemCount '未開封メール数
l_cnt = m_Folder.Items.Count 'メール総数

If l_unread <> 0 Then '未読メールがあるとき

   ReDim act(l_unread) As Variant '宛先
   ReDim frm(l_unread) As Variant '送信者アドレス
   ReDim sday(l_unread) As Variant 'メール送信日時
   ReDim rday(l_unread) As Variant 'メール受信日時
   ReDim sbj(l_unread) As Variant 'メールタイトル
   ReDim msg(l_unread) As Variant 'メール本文
 
    i = 1 '未読メール初期値

   'メールを一件目から見ていく
   For m = 1 To l_cnt 

      Set m_Item = m_Folder.Items(m) 'メール開く

      If m_Item.unread = True Then '未開封のメールだけを開く
         act(i) = m_Item.To'宛先
         Set m_RecvItem = m_Item.Reply '一度返信してアドレスを取り出す。
         frm(i) = m_RecvItem.Recipients(1).address 'メール送信者アドレス
         sday(i) = m_Item.senton 'メール送信日時
         rday(i) = m_Item.ReceivedTime 'メール受信日時
         sbj(i) = m_Item.Subject 'メールサブジェクト
         msg(i) = m_Item.Body 'メール本文
         'メールを開封する (この処理をしないと、
         'データを取り出しても未読状態のままになる)
         m_Folder.Items(m).unread = False

         MsgBox "宛先:" & act(i) & vbNewLine & _
               "送信者アドレス:" & frm(i) & vbNewLine & _
               "送信日時:" & sday(i) & vbNewLine & _
               "受信日時:" & rday(i) & vbNewLine & _
               "サブジェクト:" & sbj(i) & vbNewLine & _
               "本文:" & msg(i)
               i = i + 1
      End If
   Next
End If 	  
	  

まず、メール総数（未読＋既読）と未読メール件数を取得します。未読メール数分の変数を定義して、全メールを既読・未読で判断し、未読であればその内容を変数にセットしていきます。

5： OutLookの終了

フォームのクローズイベントプロシージャに下記のコードを記述して下さい。

'outlookの終了
m_OLApp.Quit

'オブジェクトの開放
Set m_OLApp = Nothing
Set m_Namespace = Nothing
Set m_Folder = Nothing
Set m_Item = Nothing